#脚本功能：利用LPC和窄带谐波频谱叠加图粗略观察鼻音反共振峰（anti-formant)
#写作日期：2020年2月26日
#脚本作者：张明辉（北京华睿宝科技有限公司）
#脚本运行步骤：
#	① 选中声音，点击View & Edit
#	② 在声音窗口里选中鼻音稳定段的某个时刻（一般可选鼻音段中点）
#	③ 点击Run运行脚本，在弹出的对话框中选择Male还是Female；
#	④ 在生成的绘图窗口中，根据LPC和FFT叠加图上的第一个明显的discrepancy，大致确定反共振峰的位置

name$ = selected$("Sound")
editor: "Sound 'name$'"
	midT = Get cursor
	Close
endeditor

form information
	optionmenu Gender: 1
		option Male
		option Female
endform

resample = if gender = 1 then 10000 else 11000 fi
maxF = resample/2

name$ = selected$("Sound")
selectObject: "Sound 'name$'"
Resample: resample, 50
nameR$ = selected$("Sound")
To Spectrogram: 0.03, maxF, 0.002, 20, "Gaussian"
Rename: "'name$'_FFT"
To Spectrum (slice): midT
Erase all
Black
Select outer viewport: 0, 6, 0, 4
Draw: 0, 0, 20, 120, "yes"
Marks bottom every: 1, 500, "yes", "yes", "no"
Green
selectObject: "Sound 'nameR$'"
To LPC (autocorrelation): 10, 0.025, 0.005, 50
Rename: "'name$'_LPC"
To Spectrum (slice): midT, 20, 0, 50
Rename: "'name$'_LPC"
Select outer viewport: 0, 6, 0, 4
Draw: 0, 0, -15, 85, "no"
Black

Select outer viewport: 7, 13, 0, 4
selectObject: "Spectrum 'name$'_FFT"
Draw: 0, 0, 0, 0, "yes"
Marks bottom every: 1, 500, "yes", "yes", "no"
Red
Select outer viewport: 7, 13, 0, 4
selectObject: "Spectrum 'name$'_LPC"
Draw: 0, 0, 0, 0, "no"
Black

selectObject: "Spectrum 'name$'_FFT"
View & Edit

selectObject: "Sound 'nameR$'"
plusObject: "Spectrogram 'name$'_FFT"
plusObject: "Spectrum 'name$'_LPC"
plusObject: "LPC 'name$'_LPC"
Remove
selectObject: "Sound 'name$'"